Si se ha clonado previamente el equipo, el RMS no estará funcionando bien ya que el identificador del equipo será el del equipo original (del que usamos para crear el clon). Para evitar esto, hay que limpiar ciertas claves del registro y volver a crearlas usando el comando ClientMRInit, pero conservando algunas otras para que no se pierda totalmente la información del equipo.
Para comprobar si éste es efectivamente el problema, basta con lanzar Inicio / Todos los Programas / Sophos / Endpoint / Ver el Estado de la Red de Sophos
Esto abrirá un Internet Explorer y nos informa del estado del servicio RMS. Como se puede ver a continuación, el nombre del equipo no coincide con el nombre del router RMS. En este caso el nombre del router RMS es el nombre del equipo padre de los clones; El Nombre del ordenador es el nombre del Clon. Para que Sophos funcione deben coincidir.
Para ello, vamos a usar el siguiente script:
-------------------------------------------------------------------------------------------------------------------------------------------------------------
@echo off
rem
rem Ultima modificacion: 2014/07/18
rem
set sFicheroLOG=%WINDIR%\TEMP\Metafrase-RMSReinit.log
rem ----------------------------------------------------------------------------------------
set sREGISTRYKEY64="HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Sophos\Messaging System\Router"
set sREGKEYPREF64="HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Sophos"
set sREGISTRYKEY32="HKEY_LOCAL_MACHINE\SOFTWARE\Sophos\Messaging System\Router"
set sREGKEYPREF32="HKEY_LOCAL_MACHINE\SOFTWARE\Sophos"
rem ----------------------------------------------------------------------------------------
rem clave de Registro para S.O. de 64 bits
rem
reg query HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node 2>&1
if %errorlevel% == 1 goto Sistema32bit
echo - Maquina de 64 bits >>%sFicheroLOG%
set sREGISTRYHEAD=%sREGKEYPREF64%
set sPROGRAMFILES=%ProgramFiles(x86)%
goto CambioRegistro
:Sistema32bit
echo - Maquina de 32 bits >>%sFicheroLOG%
set sREGISTRYHEAD=%sREGKEYPREF32%
set sROOTKEY="HKEY_LOCAL_MACHINE\SOFTWARE"
set sPROGRAMFILES=%ProgramFiles%
:CambioRegistro
rem
:ReiniciarRMS
echo - RESET del RMS >> %sFicheroLOG%
net stop "sophos agent" >> %sFicheroLOG%
net stop "sophos message router" >> %sFicheroLOG%
pushd .
cd "%WINDIR%\TEMP"
reg export "%sREGISTRYHEAD%\Messaging System\Router" before
reg delete "%sREGISTRYHEAD%\Messaging System" /f
reg delete "%sREGISTRYHEAD%\Remote Management System\ManagementAgent\Private" /f
reg export "%sREGISTRYHEAD%\Remote Management System\ManagementAgent" before_agent
reg delete "%sREGISTRYHEAD%\Remote Management System" /f
pushd .
cd "%sPROGRAMFILES%\Sophos\Remote Management System"
"%sPROGRAMFILES%\Sophos\Remote Management System\clientmrinit.exe" >> %sFicheroLOG%
popd
rem cd "%WINDIR%\TEMP"
reg export "%sREGISTRYHEAD%\Messaging System\Router" after
find /v "" < after > after.txt
find "ServiceHomeDir" < before >> after.txt
reg import after.txt
reg import before_agent
popd
net start "sophos message router" >> %sFicheroLOG%
net start "sophos agent" >> %sFicheroLOG%
-------------------------------------------------------------------------------------------------------------------------------------------------------------
Lo único que hay que hacer es ejecutarlo con permisos administrativos en cada máquina afectada. (En cada clon).
Después de la ejecución del script, si lanzamos :
Inicio / Todos los Programas / Sophos / Sophos Endpoint / Ver el Estado de la red de Sophos
Tenemos que comprobar que los 2 nombres (identificadores de equipo ahora ya coinciden):